upgpkg: pamac-cli-1:11.7.3-2: new upstream release

PKGBUILD

@@ -0,0 +1,62 @@
+# Maintainer: Christian Schendel <doppelhelix@gmail.com>
+# Maintainer: Mark Wagie <mark at manjaro dot org>
+# Maintainer: Philip Müller <philm@manjaro.org>
+# Contributor: Guillaume Benoit <guillaume@manjaro.org>
+
+pkgname=pamac-cli
+pkgver=11.7.3
+pkgrel=2
+epoch=1
+pkgdesc="A CLI Package Manager based on libalpm with AUR support"
+arch=('x86_64' 'aarch64')
+url="https://github.com/manjaro/pamac-cli"
+license=('GPL-3.0-or-later')
+depends=(
+    glibc
+    glib2
+    'libpamac>=11.7.0'
+)
+optdepends=(
+    'plymouth: offline upgrade support'
+)
+makedepends=(
+    asciidoc
+    git
+    meson
+    vala
+)
+conflicts=('pamac<=7.3.4-2')
+source=("git+https://github.com/manjaro/pamac-cli.git#tag=$pkgver")
+b2sums=('eb984ecb1d84bcacb3e563eb387a0eb1022ac5efc30a3b3d52d5f3905ed3e04db2d8a81ccf699bed8c089d122a38fdd66e450e4be7f4f7f6b79eeddeff068caa')
+
+_backports=(
+    9a836d69876f925f08af752e3825695b01ab6e93
+    1953797ae16a455ace764202e91849284c67b2cb
+)
+
+prepare() {
+    cd "$pkgname"
+
+    local _c _l
+    for _c in "${_backports[@]}"; do
+        if [[ "${_c}" == *..* ]]; then _l='--reverse'; else _l='--max-count=1'; fi
+        git --no-pager log --oneline "${_l}" "${_c}"
+        git cherry-pick --mainline 1 --no-commit "${_c}"
+    done
+    for _c in "${_reverts[@]}"; do
+        if [[ "${_c}" == *..* ]]; then _l='--reverse'; else _l='--max-count=1'; fi
+        git --no-pager log --oneline "${_l}" "${_c}"
+        git revert --mainline 1 --no-commit "${_c}"
+    done
+}
+
+build() {
+    arch-meson "$pkgname" build
+    meson compile -C build
+}
+
+package() {
+    meson install -C build --no-rebuild --destdir "$pkgdir"
+}
+
+# vim: set ts=4 sw=4 et: