# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Maintainer: Mark Wagie <mark at manjaro dot org>
# Maintainer: Philip Müller <philm@manjaro.org>
# Contributor: Guillaume Benoit <guillaume@manjaro.org>

pkgname=pamac-cli
pkgver=11.7.4
pkgrel=1
epoch=1
pkgdesc="A CLI Package Manager based on libalpm with AUR support"
arch=('x86_64' 'aarch64')
url="https://github.com/manjaro/pamac-cli"
license=('GPL-3.0-or-later')
depends=(
    glibc
    glib2
    'libpamac>=11.7.4'
)
optdepends=(
    'plymouth: offline upgrade support'
)
makedepends=(
    asciidoc
    git
    meson
    vala
)
conflicts=('pamac<=7.3.4-2')
source=("git+https://github.com/manjaro/pamac-cli.git#tag=$pkgver")
b2sums=('24fb674e9e6be688f53ec64c678443a80662d7a6f1d002ff230a6a5d82a7bb515077c34532423f392ab70d24fb3503a25a3fd48398f67a1fa310defff6274946')

_backports=(
)

prepare() {
    cd "$pkgname"

    local _c _l
    for _c in "${_backports[@]}"; do
        if [[ "${_c}" == *..* ]]; then _l='--reverse'; else _l='--max-count=1'; fi
        git --no-pager log --oneline "${_l}" "${_c}"
        git cherry-pick --mainline 1 --no-commit "${_c}"
    done
    for _c in "${_reverts[@]}"; do
        if [[ "${_c}" == *..* ]]; then _l='--reverse'; else _l='--max-count=1'; fi
        git --no-pager log --oneline "${_l}" "${_c}"
        git revert --mainline 1 --no-commit "${_c}"
    done
}

build() {
    arch-meson "$pkgname" build
    meson compile -C build
}

package() {
    meson install -C build --no-rebuild --destdir "$pkgdir"
}

# vim: set ts=4 sw=4 et: