# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Maintainer: Mark Wagie <mark at manjaro dot org>
# Maintainer: Philip Müller <philm@manjaro.org>
# Contributor: Guillaume Benoit <guillaume@manjaro.org>
# Contributor: Helmut Stult

pkgname=pamac-gtk
pkgver=11.7.3
pkgrel=6
epoch=1
pkgdesc="A Package Manager based on libalpm with AUR and Appstream support (GTK4)"
arch=('x86_64' 'aarch64')
url="https://github.com/manjaro/pamac"
license=('GPL-3.0-or-later')
depends=(
    'archlinux-appstream-data'
    'gdk-pixbuf2'
    'glib2'
    'glibc'
    'gtk3'
    'gtk4'
    'hicolor-icon-theme'
    'jemalloc'
    'libadwaita'
    'libnotify'
    'libpamac>=11.7.0'
    'pamac-cli>=11.7.0'
)
makedepends=(
    'asciidoc'
    'git'
    'gobject-introspection'
    'meson'
    'vala'
)
source=(
    "${pkgname}::git+https://github.com/manjaro/pamac.git#tag=v$pkgver"
    "gnome49.patch")
b2sums=('b30be55c499447044c3b15854df868c878cf562855e101445933e79db6ad7f53aa9ae38d5353f8783c534de9a07f094f96757d00b093d3c628ad863645ef9cf7'
        '25d6220c025fe0bcdcb08d511741726ae223178aa3d1bc0299d093e7d5e40febdccb788021d5ae9257af8e8bf970abe681494b7ad4993b6a4d57208db9361e51')

_backports=(
    b969d691d2f844895f28ee9538d409e1df8fd4a0
    1694ab0bf477a854133c8028de850b42baf6a75e
    f756a059f79cdeadcd2f13ebbe9aef8591ef6cb6
    8059a5ca034932cb65dfa03460ac0dfa0e391b6b
    2dc9bb20027600300eb071760e43d58ba5b66046
    99cf8daf4898f53a8285e1a6f9d9bb3f23e723ea
    3551ad1ef595eea05beed15475cf63b1c9aa2b84
    950bb26d7d6025c5d4538c992da41ec67226634c
    258fa6ba1ea54b0c93e2c553fd31f852b16f45e9
)

prepare() {
    cd "${pkgname}"
    local src
    for src in "${source[@]}"; do
        src="${src%%::*}"
        src="${src##*/}"
        [[ $src = *.patch ]] || continue
        echo "Applying patch $src..."
        patch -Np1 < "../$src"
    done

    # adjust version string
    sed -i -e "s|\"$pkgver\"|\"$pkgver-$pkgrel\"|g" src/version.vala
  
    local _c _l
    for _c in "${_backports[@]}"; do
        if [[ "${_c}" == *..* ]]; then _l='--reverse'; else _l='--max-count=1'; fi
        git --no-pager log --oneline "${_l}" "${_c}"
        git cherry-pick --mainline 1 --no-commit "${_c}"
    done
    for _c in "${_reverts[@]}"; do
        if [[ "${_c}" == *..* ]]; then _l='--reverse'; else _l='--max-count=1'; fi
        git --no-pager log --oneline "${_l}" "${_c}"
        git revert --mainline 1 --no-commit "${_c}"
    done
}

build() {
    arch-meson "${pkgname}" build \
        -Denable-fake-gnome-software=false \
        -Djemalloc=true
    meson compile -C build
}

check() {
    cd "${pkgname}"
    desktop-file-validate data/applications/*.desktop || :
}

package() {
    optdepends=(
        'pamac-gnome-integration: for integration into GNOME'
        'libpamac-flatpak-plugin: for Flatpak support'
        'libpamac-snap-plugin: for Snap support'
    )
    provides=(
        'pamac'
        'libpamac-gtk.so'
    )
    conflicts=(
        'pamac-gtk3'
    )
    install="${pkgname}.install"

    meson install -C build --no-rebuild --destdir "$pkgdir"
}

# vim: set ts=4 sw=4 et: