# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Maintainer: Mark Wagie <mark at manjaro dot org>
# Maintainer: Philip Müller <philm@manjaro.org>
# Contributor: Guillaume Benoit <guillaume@manjaro.org>
# Contributor: Helmut Stult

pkgname=pamac-gtk
pkgver=11.7.4
pkgrel=1
epoch=1
pkgdesc="A Package Manager based on libalpm with AUR and Appstream support (GTK4)"
arch=('x86_64' 'aarch64')
url="https://github.com/manjaro/pamac"
license=('GPL-3.0-or-later')
depends=(
    'archlinux-appstream-data'
    'gdk-pixbuf2'
    'glib2'
    'glibc'
    'gtk3'
    'gtk4'
    'hicolor-icon-theme'
    'libadwaita'
    'libnotify'
    'libpamac>=11.7.4'
    'pamac-cli>=11.7.40'
)
makedepends=(
    'asciidoc'
    'git'
    'gobject-introspection'
    'meson'
    'vala'
)
source=(
    "${pkgname}::git+https://github.com/manjaro/pamac.git#tag=v$pkgver")
b2sums=('84e281926218e7a8cc8f5f1ac3513e30f3b53c5f3899078e063ff4744136e6dc996100219becf8f16f035fd688f00e768349a635f73939c339e90bc81413a2a5')

_backports=(
)

prepare() {
    cd "${pkgname}"
    local src
    for src in "${source[@]}"; do
        src="${src%%::*}"
        src="${src##*/}"
        [[ $src = *.patch ]] || continue
        echo "Applying patch $src..."
        patch -Np1 < "../$src"
    done

    # adjust version string
    sed -i -e "s|\"$pkgver\"|\"$pkgver-$pkgrel\"|g" src/version.vala
  
    local _c _l
    for _c in "${_backports[@]}"; do
        if [[ "${_c}" == *..* ]]; then _l='--reverse'; else _l='--max-count=1'; fi
        git --no-pager log --oneline "${_l}" "${_c}"
        git cherry-pick --mainline 1 --no-commit "${_c}"
    done
    for _c in "${_reverts[@]}"; do
        if [[ "${_c}" == *..* ]]; then _l='--reverse'; else _l='--max-count=1'; fi
        git --no-pager log --oneline "${_l}" "${_c}"
        git revert --mainline 1 --no-commit "${_c}"
    done
}

build() {
    arch-meson "${pkgname}" build \
        -Denable-fake-gnome-software=false
    meson compile -C build
}

check() {
    cd "${pkgname}"
    desktop-file-validate data/applications/*.desktop || :
}

package() {
    optdepends=(
        #'pamac-gnome-integration: for integration into GNOME'
        'libpamac-flatpak-plugin: for Flatpak support'
        'libpamac-snap-plugin: for Snap support'
    )
    provides=(
        'pamac'
        'libpamac-gtk.so'
    )
    conflicts=(
        'pamac-gtk3'
    )
    install="${pkgname}.install"

    meson install -C build --no-rebuild --destdir "$pkgdir"

}

# vim: set ts=4 sw=4 et: