# Maintainer: Christian Schendel <doppelhelix@gmail.com>

pkgname=pandoc-bin
pkgver=3.8.2
pkgrel=1
pkgdesc="Conversion between documentation formats"
url="https://pandoc.org"
license=(
    GPL-2.0-or-later
)
arch=(
    x86_64
    aarch64
)
conflicts=(
    "pandoc-cli"
)
provides=(
    "pandoc=$pkgver"
    "pandoc-cli=$pkgver"
)
optdepends=(
    'pandoc-crossref: for numbering figures, equations, tables and cross-references to them with pandoc-crossref filter'
    'texlive-context: for pdf output using context engine'
    'groff: for pdf output using pdfroff engine'
    'python-weasyprint: for pdf output using weasyprint engine'
    'typst: for pdf output using typst engine'
    'tectonic: for pdf output using tectonic engine'
    'texlive-fontsrecommended: for pdf output using latex or xelatex engines'
    'texlive-latex: for pdf output using pdflatex engine'
    'texlive-xetex: for pdf output using xelatex engine'
)

# The binary release doesn't have the datafiles, so we need to yoink those out of the source tarball, too.
source=("$pkgname-$pkgver.tar.gz::https://github.com/jgm/pandoc/archive/${pkgver}.tar.gz")
source_x86_64=("https://github.com/jgm/pandoc/releases/download/${pkgver}/pandoc-${pkgver}-linux-amd64.tar.gz")
source_aarch64=("https://github.com/jgm/pandoc/releases/download/${pkgver}/pandoc-${pkgver}-linux-arm64.tar.gz")

b2sums=('5740cff60824f6523381182ba50c2717e3cbdc62166cac974d4378553b0ebb9c921209a4435967d4b451fb72a6985af29b596dab30b12aa6a37299ba776bb102')
b2sums_x86_64=('29b79d114adcdfb34ce4550ca966e7cb3192a9efea73440825a5bdf4c8d33fa505a5005ee5ed0c54dc199a6f0f6354b7bcc021b04ce88a2493b693603236a988')
b2sums_aarch64=('2e1da4cc0740aa294d8ec315d74bee17527d227b01280ebe26dd306d5a78b28eacce199b0af4934511081e97ac68148fe0f261f2df87fa79c146dbe5c752058d')

package() {
    cd "${srcdir}/pandoc-${pkgver}"

    mkdir -p "${pkgdir}/usr/share/pandoc"
    cp -R bin share "${pkgdir}/usr"
    cp -R data citeproc "${pkgdir}/usr/share/pandoc/"
    cp COPYRIGHT MANUAL.txt "${pkgdir}/usr/share/pandoc/"
}

# vim: set ft=sh ts=4 sw=4 et: