# Maintainer: Christian Schendel <doppelhelix@gmail.com>

pkgname=pandoc-bin
pkgver=3.8.3
pkgrel=1
pkgdesc="Conversion between documentation formats"
url="https://pandoc.org"
license=(
    GPL-2.0-or-later
)
arch=(
    x86_64
    aarch64
)
conflicts=(
    "pandoc-cli"
)
provides=(
    "pandoc=$pkgver"
    "pandoc-cli=$pkgver"
)
optdepends=(
    'pandoc-crossref: for numbering figures, equations, tables and cross-references to them with pandoc-crossref filter'
    'texlive-context: for pdf output using context engine'
    'groff: for pdf output using pdfroff engine'
    'python-weasyprint: for pdf output using weasyprint engine'
    'typst: for pdf output using typst engine'
    'tectonic: for pdf output using tectonic engine'
    'texlive-fontsrecommended: for pdf output using latex or xelatex engines'
    'texlive-latex: for pdf output using pdflatex engine'
    'texlive-xetex: for pdf output using xelatex engine'
)

# The binary release doesn't have the datafiles, so we need to yoink those out of the source tarball, too.
source=("$pkgname-$pkgver.tar.gz::https://github.com/jgm/pandoc/archive/${pkgver}.tar.gz")
source_x86_64=("https://github.com/jgm/pandoc/releases/download/${pkgver}/pandoc-${pkgver}-linux-amd64.tar.gz")
source_aarch64=("https://github.com/jgm/pandoc/releases/download/${pkgver}/pandoc-${pkgver}-linux-arm64.tar.gz")

b2sums=('4ea0bd8568c8e7a60a4703ad3f2f6817e7ce6b62dc8f7ce29bebafb2261cabd13ed9da21500789c5b6efa30eaa83a991122a1b79da82cfcb97b3900e2927c34b')
b2sums_x86_64=('4ede6aff3a09cec1931296c7034fbbdf8a0a44e77aae5c40d901493bc34e6ef20582860e9df779ef11108ef76d12402df49487fa1e653fbe11386d566abc2c62')
b2sums_aarch64=('104d3ba3b906180e761f1d82e9752ad8f8a6a57771db2ece5f4e12694884d576c7e7846dee711362658a515660d0f84b84b1637d1d23084a4a5865090eb94f91')

package() {
    cd "${srcdir}/pandoc-${pkgver}"

    mkdir -p "${pkgdir}/usr/share/pandoc"
    cp -R bin share "${pkgdir}/usr"
    cp -R data citeproc "${pkgdir}/usr/share/pandoc/"
    cp COPYRIGHT MANUAL.txt "${pkgdir}/usr/share/pandoc/"
}

# vim: set ft=sh ts=4 sw=4 et: