# Maintainer: Christian Schendel <doppelhelix@gmail.com>

pkgname=pandoc-bin
pkgver=3.8.2.1
pkgrel=1
pkgdesc="Conversion between documentation formats"
url="https://pandoc.org"
license=(
    GPL-2.0-or-later
)
arch=(
    x86_64
    aarch64
)
conflicts=(
    "pandoc-cli"
)
provides=(
    "pandoc=$pkgver"
    "pandoc-cli=$pkgver"
)
optdepends=(
    'pandoc-crossref: for numbering figures, equations, tables and cross-references to them with pandoc-crossref filter'
    'texlive-context: for pdf output using context engine'
    'groff: for pdf output using pdfroff engine'
    'python-weasyprint: for pdf output using weasyprint engine'
    'typst: for pdf output using typst engine'
    'tectonic: for pdf output using tectonic engine'
    'texlive-fontsrecommended: for pdf output using latex or xelatex engines'
    'texlive-latex: for pdf output using pdflatex engine'
    'texlive-xetex: for pdf output using xelatex engine'
)

# The binary release doesn't have the datafiles, so we need to yoink those out of the source tarball, too.
source=("$pkgname-$pkgver.tar.gz::https://github.com/jgm/pandoc/archive/${pkgver}.tar.gz")
source_x86_64=("https://github.com/jgm/pandoc/releases/download/${pkgver}/pandoc-${pkgver}-linux-amd64.tar.gz")
source_aarch64=("https://github.com/jgm/pandoc/releases/download/${pkgver}/pandoc-${pkgver}-linux-arm64.tar.gz")

b2sums=('e78658c30c57bd2c73e900067a082081ce58fc77ebdb4d0d3619024de7aa7de16a3522217846b80802a235601280b861f1f451e93eff76d19914632b79e4f5f3')
b2sums_x86_64=('c8211a6fed3161dada21ea8dfe58aadb064bca6514c7aa3910c6c3d72f457439972a43ccdd4df0f898af9105b83c5373bc083c8b2b9f6bc004ebaed0b94a931c')
b2sums_aarch64=('00965b17e165183cebac7e4eed1c5c84ed67087471350e5ba7d119a46eebd75751dd302fd3d81491bb38d4c3d66a624e04e6429f6bb564f0669756a3fb737a7a')

package() {
    cd "${srcdir}/pandoc-${pkgver}"

    mkdir -p "${pkgdir}/usr/share/pandoc"
    cp -R bin share "${pkgdir}/usr"
    cp -R data citeproc "${pkgdir}/usr/share/pandoc/"
    cp COPYRIGHT MANUAL.txt "${pkgdir}/usr/share/pandoc/"
}

# vim: set ft=sh ts=4 sw=4 et: