# Maintainer: Christian Schendel <doppelhelix@gmail.com>

pkgname=pandoc-bin
pkgver=3.8
pkgrel=1
pkgdesc="Conversion between documentation formats"
url="https://pandoc.org"
license=(
    GPL-2.0-or-later
)
arch=(
    x86_64
    aarch64
)
conflicts=(
    "pandoc-cli"
)
provides=(
    "pandoc=$pkgver"
    "pandoc-cli=$pkgver"
)
optdepends=(
    'pandoc-crossref: for numbering figures, equations, tables and cross-references to them with pandoc-crossref filter'
    'texlive-context: for pdf output using context engine'
    'groff: for pdf output using pdfroff engine'
    'python-weasyprint: for pdf output using weasyprint engine'
    'typst: for pdf output using typst engine'
    'tectonic: for pdf output using tectonic engine'
    'texlive-fontsrecommended: for pdf output using latex or xelatex engines'
    'texlive-latex: for pdf output using pdflatex engine'
    'texlive-xetex: for pdf output using xelatex engine'
)

# The binary release doesn't have the datafiles, so we need to yoink those out of the source tarball, too.
source=("$pkgname-$pkgver.tar.gz::https://github.com/jgm/pandoc/archive/${pkgver}.tar.gz")
source_x86_64=("https://github.com/jgm/pandoc/releases/download/${pkgver}/pandoc-${pkgver}-linux-amd64.tar.gz")
source_aarch64=("https://github.com/jgm/pandoc/releases/download/${pkgver}/pandoc-${pkgver}-linux-arm64.tar.gz")

b2sums=('81a4ac5baf0ca46a140494d09a4658324ba2a1a2e7120b74507f797815f8969a006808d2a220e2591a71be4711a436dd0e53a427f6781ecb3db5708fd3818673')
b2sums_x86_64=('ec6f5a7e1f52fb86828917d2ba37b9d46852f75abf0339eab85c88c31de2e8a6263aaf56b713e62e02121675880313f16fc2debdfe0569f413d3f2275706a2d4')
b2sums_aarch64=('afc20832edf71b6cd0da77f4300ec8f68dbec34bff01d9939187dfc17118466df8aed88f76475e5877637daf360d1e6606e477beff4762fd735e768477899955')

package() {
    cd "${srcdir}/pandoc-${pkgver}"

    mkdir -p "${pkgdir}/usr/share/pandoc"
    cp -R bin share "${pkgdir}/usr"
    cp -R data citeproc "${pkgdir}/usr/share/pandoc/"
    cp COPYRIGHT MANUAL.txt "${pkgdir}/usr/share/pandoc/"
}

# vim: set ft=sh ts=4 sw=4 et: