# Maintainer: Christian Schendel <doppelhelix@gmail.com>

pkgname=pandoc-bin
pkgver=3.8.1
pkgrel=1
pkgdesc="Conversion between documentation formats"
url="https://pandoc.org"
license=(
    GPL-2.0-or-later
)
arch=(
    x86_64
    aarch64
)
conflicts=(
    "pandoc-cli"
)
provides=(
    "pandoc=$pkgver"
    "pandoc-cli=$pkgver"
)
optdepends=(
    'pandoc-crossref: for numbering figures, equations, tables and cross-references to them with pandoc-crossref filter'
    'texlive-context: for pdf output using context engine'
    'groff: for pdf output using pdfroff engine'
    'python-weasyprint: for pdf output using weasyprint engine'
    'typst: for pdf output using typst engine'
    'tectonic: for pdf output using tectonic engine'
    'texlive-fontsrecommended: for pdf output using latex or xelatex engines'
    'texlive-latex: for pdf output using pdflatex engine'
    'texlive-xetex: for pdf output using xelatex engine'
)

# The binary release doesn't have the datafiles, so we need to yoink those out of the source tarball, too.
source=("$pkgname-$pkgver.tar.gz::https://github.com/jgm/pandoc/archive/${pkgver}.tar.gz")
source_x86_64=("https://github.com/jgm/pandoc/releases/download/${pkgver}/pandoc-${pkgver}-linux-amd64.tar.gz")
source_aarch64=("https://github.com/jgm/pandoc/releases/download/${pkgver}/pandoc-${pkgver}-linux-arm64.tar.gz")

b2sums=('8f3c21eab668d5b805cf0a1ee5949af7b15b21f62158dd935cc4ef29b4e77c6d0a773e0be1b6b02b62b553ddec54317e165f3c650d99fd2a2035bf4264011492')
b2sums_x86_64=('2ffc74617acf1a4a470172b9ffb3389100c6ddc36074b0b1135089a2b30c26034a945f023f1ebc26cd2a6de879c036e822e54b563ee10abef7d7a8d33f210932')
b2sums_aarch64=('5b6b2f48c42fc321e6bdca63d09f2c2e6eb5d31629ca0e3288b8aacc8928e5fb4496a21ec50be86485f6b034938500fc5b50e6d707df180e3e35fec2e2173582')

package() {
    cd "${srcdir}/pandoc-${pkgver}"

    mkdir -p "${pkgdir}/usr/share/pandoc"
    cp -R bin share "${pkgdir}/usr"
    cp -R data citeproc "${pkgdir}/usr/share/pandoc/"
    cp COPYRIGHT MANUAL.txt "${pkgdir}/usr/share/pandoc/"
}

# vim: set ft=sh ts=4 sw=4 et: