# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: Mark Wagie <mark dot wagie at proton dot me>
# Contributor: Mohammadreza Abdollahzadeh <morealaz at gmail dot com>
# Contributor: Edgard Castro <castro@edgard.org>
# Contributor: Frederic Bezies <fredbezies at gmail dot com>
# Contributor: FadeMind <fademind@gmail.com>
# Contributor: Icaro Perseo <icaroperseo[at]protonmail[dot]com>
# Contributor: Lucas Saliés Brum <lucas@archlinux.com.br>

pkgname=papirus-icon-theme-git
pkgver=20250501.r97.g3390a630b5
pkgrel=1
pkgdesc="A free and open source SVG icon theme based on Paper Icon Set"
arch=('any')
url="https://git.io/papirus-icon-theme"
license=(
    'GPL-3.0-or-later'
)
depends=(
    'gtk-update-icon-cache'
)
makedepends=(
    'git'
)
optdepends=(
    'hardcode-fixer-git: To deal with hardcoded application icons'
    'hardcode-tray-git: To fix hardcoded tray icons'
    'sif-git: To fix icons of running Steam games'
)
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
install='alt-icons.install'
options+=(
    !strip
)
source=(
    "${pkgname%-git}::git+https://github.com/PapirusDevelopmentTeam/papirus-icon-theme.git"
    "io.git.PapirusIconTheme.metainfo.xml"
)
b2sums=('SKIP'
        '7c28927a741d47bb0ab84772110aadcb233db2d0a3a294a0fb7a7849590dd9f30bb0cfea7cb849ae77a6b52a030b9b2703bb98dbbf32fb475f714093f3b94279')

pkgver() {
    cd "$srcdir/${pkgname%-git}"
    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

package() {
    cd "$srcdir/${pkgname%-git}"
    make DESTDIR="$pkgdir" install
    install -Dm644 ../io.git.PapirusIconTheme.metainfo.xml "${pkgdir}/usr/share/metainfo/io.git.PapirusIconTheme.metainfo.xml"
}

# vim: set ft=sh ts=4 sw=4 et: