# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: Morgenstern <charles [at] charlesbwise [dot] com>

pkgname=puddletag-git
pkgver=20251009.055943
pkgrel=1
pkgdesc="An audio tag editor for GNU/Linux, git version"
url="https://github.com/puddletag/puddletag"
license=(
    GPL-3.0-or-later
)
arch=('any')
depends=(
    python
    python-configobj
    python-distro
    python-levenshtein
    python-lxml
    python-mutagen
    python-pyacoustid
    python-pyparsing
    python-pyqt6
    python-unidecode
    qt6-svg
)
makedepends=(
    git
    python-build
    python-installer
    python-setuptools
    python-wheel
)
optdepends=(
    'chromaprint: AcoustID support'
    'quodlibet: QuodLibet library support'
)
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=(
    "${pkgname%-git}-${pkgver}::git+${url}.git"
    "io.github.puddletag.puddletag.metainfo.xml"
    "puddletag.svg"
)
b2sums=('SKIP'
        '8e20b3836487da1c48bf2ba3fd570bdfe487cfb57c2d273adc6502bf22c795b6dce4e52a3e0b8f971b9846a1e1079e5a25bb8b8c7a241ac278b5bcc3fb95ee17'
        'ff23b21fae4df6d68eaeb60df9014c0994fdb8ae6c1affdc9d56fb11ee8fb1cfaeace184e696788b65967e1fd447a7e2d40c26c4dd441f61768cb545701e069d')

build() {
    cd "${pkgname%-git}-${pkgver}"
    python -m build --wheel --no-isolation -Cbuild-dir=build
}

package() {
    cd "${pkgname%-git}-${pkgver}"
    python -m installer --destdir="${pkgdir}" dist/*.whl

    install -Dm644 ../io.github.puddletag.puddletag.metainfo.xml \
        "${pkgdir}/usr/share/metainfo/io.github.puddletag.puddletag.metainfo.xml"

    install -Dm644 ../puddletag.svg \
        "${pkgdir}/usr/share/icons/hicolor/scalable/apps/puddletag.svg"
    rm -r "${pkgdir}/usr/share/pixmaps"
}
# vim: set ts=4 sw=4 et: