# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: Morgenstern <charles [at] charlesbwise [dot] com>

pkgname=puddletag
pkgver=2.5.0
pkgrel=4
pkgdesc='An audio tag editor for GNU/Linux'
url="https://github.com/puddletag/puddletag"
license=(
    GPL-3.0-or-later
)
arch=(any)
depends=(
    python
    python-certifi
    python-charset-normalizer
    python-configobj
    python-distro
    python-idna
    python-levenshtein
    python-lxml
    python-mutagen
    python-pyacoustid
    python-pyparsing
    python-pyqt5
    python-pyqt6
    python-pyqt5-sip
    python-pyqt6-sip
    python-requests
    python-unidecode
    python-urllib3
    qt5-svg
    qt6-svg
)
makedepends=(
    git
    python-build
    python-installer
    python-setuptools
    python-wheel
)
optdepends=(
    'chromaprint: AcoustID support'
    'quodlibet: QuodLibet library support'
)
source=(
    "$pkgname-$pkgver::git+$url.git#tag=$pkgver"
    "io.github.puddletag.puddletag.metainfo.xml"
)
b2sums=('cb105ddfbde9091e93fdbf42f6c469756c4593cccefbd9c23c4aa95d3305d0786f18f086bb91e9e8bf6e5d99bc6e12879cec05fe7137e75a976fdc2f9625560e'
        '8e20b3836487da1c48bf2ba3fd570bdfe487cfb57c2d273adc6502bf22c795b6dce4e52a3e0b8f971b9846a1e1079e5a25bb8b8c7a241ac278b5bcc3fb95ee17')

build() {
    cd "${pkgname}-${pkgver}"
    python -m build --wheel --no-isolation -Cbuild-dir=build
}

package() {
    cd "${pkgname}-${pkgver}"
    python -m installer --destdir="${pkgdir}" dist/*.whl
    install -Dm644 ../io.github.puddletag.puddletag.metainfo.xml \
        "${pkgdir}/usr/share/metainfo/io.github.puddletag.puddletag.metainfo.xml"
}
# vim: set ft=sh ts=4 sw=4 et: