# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: mattski <redmattski at gmail dot com>
# Contributor: Winux <winux@winux.cc>

pkgname=python-audible-cli
#_name=${pkgname#python-}
pkgver=0.3.3
pkgrel=1
pkgdesc='A command line interface for audible package. With the cli you can download your Audible books, cover, chapter files.'
arch=(any)
url="https://github.com/mkb79/audible-cli"
license=(
    AGPL-3.0-only
)
depends=(
    python
    python-aiofiles
    python-audible
    python-click
    python-httpx
    python-packaging
    python-pillow
    python-questionary
    python-tabulate
    python-toml
    python-tqdm
)
makedepends=(
    git
    python-build
    python-hatchling
    python-installer
    python-setuptools
    python-wheel
)
source=(
    "$pkgname-$pkgver::git+$url.git#tag=v$pkgver"
)
b2sums=('1ce7efaefa7a62fb6520406e7f19941ca278d9edec41dc8aad2a86f54adf540696c2dfa803897515bb6f2563281d1100febc9b5c7c49b22daffe8e51d9b1ac2a')

build() {
    cd "$pkgname-$pkgver"
    python -m build --wheel --no-isolation
}

package() {
    cd "$pkgname-$pkgver"
    python -m installer --destdir="$pkgdir" dist/*.whl
}