# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: Chris Billington <chrisjbillington@gmail.com>
pkgname=python-questionary
_name=${pkgname#python-}
pkgver=2.1.1
pkgrel=2
pkgdesc="Python library to build pretty command line user prompts"
license=(
    MIT
)
url="https://pypi.python.org/pypi/$_name"
depends=(
    python
    python-prompt_toolkit
)
makedepends=(
    python-build
    python-installer
    python-wheel
    python-poetry-core
)
source=("https://files.pythonhosted.org/packages/source/${_name::1}/$_name/$_name-$pkgver.tar.gz")
b2ums=('6302cdd645b19667d8f6e6634774e9538bfcd1aad9be287e743d96cacaf95587')
arch=('any')

prepare() {
    cd "$_name-$pkgver"
    sed -i -E "/^prompt_toolkit =/s/,.*$/\"/" pyproject.toml
}

build() {
    cd "$_name-$pkgver"
    python -m build --wheel --no-isolation
}

package() {
    cd "$_name-$pkgver"
    python -m installer --destdir="$pkgdir" dist/*.whl
    install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}
b2sums=('6884a73f713662c9827858df6151d57221e80590e8fd71f72ae2a0af592a91a91965ed0175ec64e3841a422e34aa75fe28c180299baf38279c83bb1c8e4bab94')