# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=python-steam
_name=${pkgname#python-}
pkgver=1.6.1
epoch=1
pkgrel=1
pkgdesc="Python package for interacting with Steam"
arch=('any')
url="https://github.com/solsticegamestudios/steam"
license=(
    MIT
)
depends=(
    python
    python-cachetools
    python-pycryptodomex
    python-requests
    python-six
    python-vdf
)
makedepends=(
    python-build
    python-installer
    python-setuptools
    python-wheel
)
source=(
    "$_name-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz"
)
b2sums=('b02fcfbab0a3fba49eedc66720f50c3c191b01a0361500c5c8bb24c685bc6a463f25185bbb128483d8bd65a63474ed40689dd3174205610438295dd7e9e0b324')

build() {
    cd "$_name-$pkgver"
    python -m build --wheel --no-isolation
}

package() {
    cd "$_name-$pkgver"
    python -m installer --destdir="$pkgdir" dist/*.whl

    install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
}