Initial commit

PKGBUILD

@@ -0,0 +1,51 @@
+# Maintainer: Christian Schendel <doppelhelix@gmail.com>
+# Contributor: Christian Rebischke <chris.rebischke@archlinux.org>
+# Contributor: Morten Linderud <morten@linderud.pw>
+
+pkgname=python-vagrant
+pkgver=1.1.0
+pkgrel=3
+pkgdesc="Python bindings for interacting with Vagrant virtual machines."
+url="https://github.com/todddeluca/python-vagrant"
+license=('MIT')
+arch=('any')
+depends=(
+    python
+)
+makedepends=(
+    git
+    python-build
+    python-installer
+    python-setuptools-scm
+    python-wheel
+)
+#checkdepends=('vagrant')
+source=(git+https://github.com/pycontribs/python-vagrant#tag=v$pkgver)
+b2sums=('2d10574dec7210bfa59bd2d6e2b75ebbab9dc26cd1dc0435f203548d8db8b09a1d8bf982b25066c0f5c7bca758938894b067cd4c9e44f0d110eee2e593a96a49')
+
+prepare() {
+    cd ${pkgbase}
+
+    sed -e '/setuptools_scm_git_archive/d' -i pyproject.toml
+}
+
+build() {
+    cd ${pkgbase}
+
+    SETUPTOOLS_SCM_PRETEND_VERSION="$pkgver" python -m build --wheel --no-isolation
+}
+
+# Disabled, because they need Vagrant. Systemd-nspawn doesn't support this.
+#check() {
+#  cd "${srcdir}/${pkgbase}-${pkgver}"
+#  python setup.py test
+#}
+
+package() {
+    cd ${pkgbase}
+
+    python -m installer --destdir="${pkgdir}" dist/*.whl
+
+    # license
+    install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE.txt
+}