# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: Antonio Rojas <arojas@archlinux.org>
# Contributor: Martchus <martchus@gmx.net>

pkgname=qt6ct-kde
pkgver=0.11
pkgrel=1
pkgdesc='Qt 6 Configuration Utility, patched to work correctly with KDE applications'
arch=(x86_64)
url='https://www.opencode.net/trialuser/qt6ct'
license=(
    BSD-2-Clause
)
depends=(
    gcc-libs
    glibc
    kcolorscheme
    kconfig
    kiconthemes
    qqc2-desktop-style
    qt6-base
    qt6-declarative
)
makedepends=(
    cmake
    git
    qt6-tools
    vulkan-headers
)
conflicts=("qt6ct")
provides=("qt6ct")
source=(
    "${pkgname}-${pkgver}::git+${url}.git#tag=${pkgver}"
    "qt6ct-shenanigans.patch::https://aur.archlinux.org/cgit/aur.git/plain/qt6ct-shenanigans.patch?h=${pkgname}"
)
b2sums=('11329909eb3d3f15d7665133e076120a5af668c700889ea1d9ad03c6e7f17358259b2f8e02f0261d52e9d9a17b93521e6e6ce9465d481f691734e78c639abebb'
        'abd51a72a85178004949bc5cb644856cf258c5778a1b5d24a277f18f8f26009b795fffa29de2bd19cf9492c9a96b00dc55c335cb81cd56b173e3d4d0638b1e63')


prepare() {
    patch -d $pkgname-$pkgver -Np1 -i ../qt6ct-shenanigans.patch
}

build() {
    local cmake_options=(
        -B build
        -S "$pkgname-$pkgver"
        -D CMAKE_INSTALL_PREFIX=/usr
        -W no-dev
    )
    cmake "${cmake_options[@]}"
    cmake --build build
}

package() {
    DESTDIR="$pkgdir" cmake --install build
    install -Dm0644 "$pkgname-$pkgver/COPYING" \
        "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

# vim: set ts=4 sw=4 et: