# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: Antonio Rojas <arojas@archlinux.org>
# Contributor: Martchus <martchus@gmx.net>

pkgname=qt6ct-kde
pkgver=0.10
pkgrel=6
pkgdesc='Qt 6 Configuration Utility, patched to work correctly with KDE applications'
arch=(x86_64)
url='https://github.com/ilya-fedin/qt6ct'
license=(
    BSD-2-Clause
)
depends=(
    gcc-libs
    glibc
    kcolorscheme
    kconfig
    kiconthemes
    qqc2-desktop-style
    qt6-base
    qt6-declarative
)
makedepends=(
    cmake
    git
    qt6-tools
    vulkan-headers
)
conflicts=("qt6ct")
provides=("qt6ct")
source=(
    "$pkgname-$pkgver::git+$url.git#tag=$pkgver"
)
b2sums=('35ba9baeaa23d08248da0bcce1d24a72e21936b922c8271ec41880dffcc74e3b02bff9ac8cb29b2435f4bd1761d592e6365d03ae169915ca7e74925f1a2da62c')


build() {
    local cmake_options=(
        -B build
        -S "$pkgname-$pkgver"
        -D CMAKE_INSTALL_PREFIX=/usr
        -W no-dev
    )
    cmake "${cmake_options[@]}"
    cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
  install -Dm0644 "$pkgname-$pkgver/COPYING" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

# vim: set ft=sh ts=4 sw=4 et: