Initial commit

PKGBUILD

@@ -0,0 +1,65 @@
+# Maintainer: Christian Schendel <doppelhelix@gmail.com>
+# Contributor: claymorwan <claymorwan@fembois.dev>
+
+pkgname=sgdboop
+_pkgname=SGDBoop
+pkgver=1.3.1
+pkgrel=2
+pkgdesc="A program used for applying custom artwork to Steam, using SteamGridDB. Supports both Windows and Linux, written completely in C."
+arch=('x86_64')
+url="https://github.com/SteamGridDB/SGDBoop"
+license=(
+    Zlib
+)
+depends=(
+    at-spi2-core
+    cairo
+    curl
+    glib2
+    glibc
+    gdk-pixbuf2
+    gtk3
+    harfbuzz
+    hicolor-icon-theme
+    pango
+    shared-mime-info
+    zlib
+)
+makedepends=(
+    gcc14
+    git
+    libcurl-gnutls
+    make
+)
+
+checkdepends=(
+    appstream
+    desktop-file-utils
+)
+provides=("$pkgname")
+conflicts=("$pkgname")
+source=("$_pkgname-$pkgver::git+$url.git#tag=v${pkgver}")
+b2sums=('1cfb5df73eb33733af89c702268bc1c859db61edc9f7a98d9fb00ae6eb0560be144bdf6db76db87428e7899a9eb621c58a5caea5eb34aeb0ce73a72b2a47bf51')
+
+build() {
+    cd "$_pkgname-$pkgver"
+    export CC=gcc-14
+    export CXX=g++-14
+    make
+}
+
+check() {
+    cd "$_pkgname-$pkgver"
+    desktop-file-validate linux-release/com.steamgriddb.SGDBoop.desktop
+    ## appstreamcli does not validate: description-has-plaintext-url
+    # appstreamcli validate --no-net com.steamgriddb.SGDBoop.appdata.xml
+}
+
+package() {
+    cd "$_pkgname-$pkgver"
+    install -Dm0755 -t "$pkgdir/usr/bin/" linux-release/SGDBoop
+    install -Dm0644 -t "$pkgdir/usr/share/applications" linux-release/com.steamgriddb.SGDBoop.desktop
+    install -Dm0644 -t "$pkgdir/usr/share/metainfo" com.steamgriddb.SGDBoop.appdata.xml
+    install -Dm0644 -t "$pkgdir/usr/share/icons/hicolor/scalable/apps/" res/com.steamgriddb.SGDBoop.svg
+    install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE
+}