# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: Nobbele <realnobbele@gmail.com>

pkgname=thinlinc-client-bin
pkgver=4.19.0_4005
pkgrel=6
pkgdesc="Cendio ThinLinc Linux remote desktop client."
url="https://www.cendio.com"
arch=(
    x86_64
    armv7h
)
license=(
    'LicenseRef-CENDIO_END_USER_LICENSE_AGREEMENT_3.5'
)

optdepends=(
    'cups: required for remote printing'
    'python-ldap: auth against ldap'
)
source_x86_64=(
    "$pkgname"-"$pkgver".tar.gz::https://www.cendio.com/downloads/clients/tl-"${pkgver//_/-}"-client-linux-dynamic-x86_64.tar.gz
)
source_armv7h=(
    "$pkgname"-"$pkgver".tar.gz::https://www.cendio.com/downloads/clients/tl-"${pkgver//_/-}"-client-linux-dynamic-armhf.tar.gz
)
source=(
    "com.cendio.thinlinc_client.metainfo.xml"
    "tlclient.csh"
    "tlclient.sh"
)
noextract=(
    "$pkgname-$pkgver.tar.gz"
)
b2sums=('c9142237dee9a47ceb132484ab30f5ebde1e22414d6bb8fb627944295313e258c6188b6b4238a438b16347b7bdbf37f5d1e30c8a3f316ae7d58574671452dbd1'
        '35f23ab16e8656e1d973391360ea52053c20227c7834454792f0c9d7e56dbe692a362c8de869a4b7371eecef3cfeeafe628803079fd4d31ee2157427e1305b1c'
        '68bd5443a2f59f7e128ce8ea60ef3d1da62f43d9e40bf4e163e28c33bfd04ab9fc1b0d11859238d8568ea1c15f831bf2316171aebbaf3e88f715cf7d6a8a5e58')
b2sums_x86_64=('a201d1ad34189f09023f9b1cd9839d414d8ccf36bcbc79380a831928b875182efb6ed11bd20ed2faa33ac386ba63374683eaadb3083d94591e27d4e9c85a245f')
b2sums_armv7h=('a201d1ad34189f09023f9b1cd9839d414d8ccf36bcbc79380a831928b875182efb6ed11bd20ed2faa33ac386ba63374683eaadb3083d94591e27d4e9c85a245f')
provides=("thinlinc-client=$pkgver")
replaces=('thinlinc-client')

prepare() {
    mkdir "$srcdir/$pkgname-$pkgver"
    bsdtar -xf "$pkgname-$pkgver.tar.gz" \
        -C "$srcdir/$pkgname-$pkgver" \
        --strip-components=1
}

package() {
    depends+=(
        alsa-lib
        bash
        glibc
        hicolor-icon-theme
        libpulse
        libx11
        openssh
        pcsclite
        pulse-native-provider
        python
        python-gobject
        zlib
    )
    cd "$srcdir/$pkgname-$pkgver"

    install -dm0755 "$pkgdir/usr"
    cp -R --no-preserve=ownership lib/tlclient/share "$pkgdir/usr"

#    cp -R --no-preserve=ownership lib/tlclient/locale "$pkgdir/usr/share"

    install -dm0755 "$pkgdir/opt/thinlinc"
    rm -R lib/tlclient/{lib,share}
    cp -R --no-preserve=ownership ./* "$pkgdir/opt/thinlinc"

    install -dm0755 "$pkgdir/usr/bin"
    ln -s "/opt/thinlinc/bin/tlclient" "$pkgdir/usr/bin/tlclient"
    ln -s "/opt/thinlinc/bin/tlclient-openconf" \
        "$pkgdir/usr/bin/tlclient-openconf"

    # Copy licenses
    install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" \
        "$pkgdir/opt/thinlinc/lib/tlclient/open_source_licenses.txt"
    install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" \
        "$pkgdir/opt/thinlinc/lib/tlclient/EULA.txt"

    # replicate the content of the .deb
    install -Dm0644 -t "$pkgdir/etc/profile.d" "$srcdir"/tlclient.{sh,csh}

    install -Dm644 "${srcdir}/com.cendio.thinlinc_client.metainfo.xml" \
        "${pkgdir}/usr/share/metainfo/com.cendio.thinlinc_client.metainfo.xml"
}

# vim: set ft=sh ts=4 sw=4 et: