# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: Mark Wagie <mark dot wagie at proton dot me>
pkgname=universal-android-debloater
pkgver=1.1.2
pkgrel=2
pkgdesc="Cross-platform GUI written in Rust using ADB to debloat non-rooted Android devices"
arch=('x86_64')
url="https://github.com/Universal-Debloater-Alliance/universal-android-debloater-next-generation"
license=(
    GPL-3.0-or-later
)
depends=(
    android-tools
    gcc-libs
    glibc
)
makedepends=(
    cargo
    clang
    cmake
    git
    mold
)
source=(
    "$pkgname-$pkgver::git+$url.git#tag=v$pkgver"
    "uad-ng.desktop"
    "io.github.universal_debloater_alliance.universal_android_debloater.metainfo.xml"
)
conflicts=(
    universal-android-debloater-opengl
)
b2sums=('6c5adb052fcbfbafad0752d02fc284abc0d4a6bc8332a98aeba9de150c75b0bbfe1e06130d5f3ea9c17bc4cb589b3b54f109f2d61f09f70e30938651c46c3f3a'
        '0f278d608e645e8f06ae178bab2f16fc82ef77d33ae05cb965266d3495af25aea99d9edfeae85dae1f5385ac4d17f2f05f784ca2039933fcb91ca9229385fce8'
        '5e7be07085326a13fcb3e73cfb549ae38bbba7ffb085e68d970677f1605abca18f09b9140cc7d355cba1c798ad999b2dadcd62ed3ea0334fea733aca34831755')

prepare() {
    cd "$pkgname-$pkgver"
    export RUSTUP_TOOLCHAIN=stable
    cargo fetch \
        --locked \
        --target "$(rustc -vV | sed -n 's/host: //p')"
}

build() {
    cd "$pkgname-$pkgver"
    CFLAGS+=" -ffat-lto-objects"
    export RUSTUP_TOOLCHAIN=stable
    export CARGO_TARGET_DIR=target
    export CARGO_PROFILE_RELEASE_STRIP=false
    cargo build \
        --frozen \
        --release \
        --no-default-features \
        --features wgpu,no-self-update
}

package() {
    cd "$pkgname-$pkgver"
    install -Dm0755 -t "$pkgdir/usr/bin/" target/release/uad-ng
    install -Dm0644 resources/assets/logo-dark.png "$pkgdir/usr/share/pixmaps/uad-ng.png"
    install -Dm0644 -t "$pkgdir/usr/share/applications/" "$srcdir/uad-ng.desktop"
    install -Dm644 "${srcdir}/io.github.universal_debloater_alliance.universal_android_debloater.metainfo.xml" \
        "${pkgdir}/usr/share/metainfo/io.github.universal_debloater_alliance.universal_android_debloater.metainfo.xml"
}

# vim: set ft=sh ts=4 sw=4 et: