# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: Mark Wagie <mark dot wagie at proton dot me>
pkgname=universal-android-debloater
pkgver=1.1.2
pkgrel=2
pkgdesc="Cross-platform GUI written in Rust using ADB to debloat non-rooted Android devices"
arch=('x86_64')
url="https://github.com/Universal-Debloater-Alliance/universal-android-debloater-next-generation"
license=(
    GPL-3.0-or-later
)
depends=(
    android-tools
    gcc-libs
    glibc
)
makedepends=(
    cargo
    clang
    cmake
    git
    mold
)
source=(
    "$pkgname-$pkgver::git+$url.git#tag=v$pkgver"
    uad-ng.desktop
)
conflicts=(
    universal-android-debloater-opengl
)
b2sums=('6c5adb052fcbfbafad0752d02fc284abc0d4a6bc8332a98aeba9de150c75b0bbfe1e06130d5f3ea9c17bc4cb589b3b54f109f2d61f09f70e30938651c46c3f3a'
        '4e1f323437031dffe0eebf8463efa81ab75d37f5010cab7a07cf6edb271cb6ba141b812c71373011373a2160008bd3625a92236ecc190c4f0eee30a71ddb9cfb')

prepare() {
    cd "$pkgname-$pkgver"
    export RUSTUP_TOOLCHAIN=stable
    cargo fetch \
        --locked \
        --target "$(rustc -vV | sed -n 's/host: //p')"
}

build() {
    cd "$pkgname-$pkgver"
    CFLAGS+=" -ffat-lto-objects"
    export RUSTUP_TOOLCHAIN=stable
    export CARGO_TARGET_DIR=target
    export CARGO_PROFILE_RELEASE_STRIP=false
    cargo build \
        --frozen \
        --release \
        --no-default-features \
        --features wgpu,no-self-update
}

package() {
    cd "$pkgname-$pkgver"
    install -Dm0755 -t "$pkgdir/usr/bin/" target/release/uad-ng
    install -Dm0644 resources/assets/logo-dark.png "$pkgdir/usr/share/pixmaps/uad-ng.png"
    install -Dm0644 -t "$pkgdir/usr/share/applications/" "$srcdir/uad-ng.desktop"
}

# vim: set ft=sh ts=4 sw=4 et: