# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: Brett Cornwall <ainola@archlinux.org>
# Contributor: Maxim Baz <archlinux at maximbaz dot com>
# Contributor: Parmjot Singh <parmjotsinghrobot at gmail dot com>

pkgname=waybar-git
pkgver=r3845.0332d2eb
pkgrel=1
pkgdesc='Highly customizable Wayland bar for Sway and Wlroots based compositors'
arch=(
    x86_64
)
url="https://github.com/Alexays/Waybar"
license=(
    MIT
)
depends=(
    atkmm
    cairomm
    fmt
    gcc-libs
    glib2
    glibc
    glibmm
    gtk-layer-shell
    gtk3
    gtkmm3
    jack
    jsoncpp
    libdbusmenu-gtk3
    libevdev
    libinput
    libmpdclient
    libnl
    libpipewire
    libpulse
    libsigc++
    libwireplumber
    libxkbcommon
    playerctl
    sndio
    spdlog
    systemd-libs
    upower
    wayland
)
makedepends=(
    git
    catch2
    cmake
    meson
    glib2-devel # gdbus-codegen
    scdoc # For generating manpages
    wayland-protocols
)
backup=(
    etc/xdg/waybar/config.jsonc
    etc/xdg/waybar/style.css
)
optdepends=(
    'otf-font-awesome: Icons in the default configuration'
)

source=(
    "$pkgname::git+$url.git"
)
b2sums=('SKIP')

conflicts=('waybar')
provides=('waybar')

pkgver() {
    cd "$srcdir/$pkgname"

    # support repositories that start without a tag but get tagged later on
    ( set -o pipefail
        git describe --long 2>/dev/null | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' ||
        printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
    )
}

#prepare() {
#    cd "$srcdir/$pkgname"
#
#    # https://github.com/Alexays/Waybar/pull/2919
#    patch -Np1 -i ../0001-Update-Wireplumber-API-to-0.5.patch
#}

build() {
    cd "$srcdir/$pkgname"
    local meson_options=(
        --prefix=/usr
        --buildtype=plain
        --auto-features=enabled
        --wrap-mode=nodownload
        -Dcpp_std=c++20
        -Dexperimental=true
        -Dcava=disabled
        -Dtests=enabled
        build
    )
    meson "${meson_options[@]}"
    meson compile -C build
}

check() {
    cd "$srcdir/$pkgname"
    meson test -C build --print-errorlogs --no-rebuild --suite waybar
}

package() {
    depends+=(
      'libatkmm-1.6.so'
      'libcairomm-1.0.so'
      'libgtk-3.so'
      'libjack.so'
      'libjsoncpp.so'
      'libpipewire-0.3.so'
      'libsndio.so'
      'libspdlog.so'
      'libudev.so'
      'libupower-glib.so'
    )
    cd "$srcdir/$pkgname"
    meson install -C build --destdir "$pkgdir"
    install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE
}

# vim: set ft=sh ts=4 sw=4 et: