# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: coffebar i8ehkvien@mozmail.com

pkgname=waybar-module-pacman-updates
pkgver=0.2.10
pkgrel=1
pkgdesc='Waybar module for Arch to show system updates available'
arch=('x86_64')
url="https://github.com/coffebar/waybar-module-pacman-updates"
license=(
    'GPL-3.0-or-later'
)
makedepends=(
    cargo
    git
)
source=("$pkgname-$pkgver::git+$url.git#tag=$pkgver")
sha256sums=('7b6a7017f6391b96561f5dec381baf02693e4c856407620be94932ffa6058e38')
options=(!lto)

prepare() {
    cd "$pkgname-$pkgver"
    export RUSTUP_TOOLCHAIN=stable
    cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}

build() {
    cd "$pkgname-$pkgver"
    export RUSTUP_TOOLCHAIN=stable
    export CARGO_TARGET_DIR=target
    cargo build --frozen --release --all-features
}

check() {
    cd "$pkgname-$pkgver"
    export RUSTUP_TOOLCHAIN=stable
    cargo test --frozen --all-features
}

package() {
    depends+=(
        curl
        gcc-libs
        glibc
        openssl
        pacman
        pacman-contrib
        waybar
    )
    cd "$pkgname-$pkgver"
    install -Dm0755 -t "$pkgdir/usr/bin/" "target/release/waybar-module-pacman-updates"
    install -Dm0644 -t "$pkgdir/usr/share/doc/$pkgname" "README.md"
    install -Dm0644 -t "$pkgdir/usr/share/doc/$pkgname" "screenshot.png"
}

# vim: set ft=sh ts=4 sw=4 et: