# Maintainer: Jason Nader <jason.nader@protonmail.com>
pkgname=wlogout-git
pkgver=1.2.2.r1.g350fe88
pkgrel=2
license=(MIT)
pkgdesc="Logout menu for wayland"
makedepends=(
    'meson'
    'git'
    'scdoc'
    'ninja'
)
depends=(
    'gtk3'
    'gobject-introspection'
    'gtk-layer-shell'
)
optdepends=(
    'swaylock: default buttons'
    'systemd: default buttons'
)
arch=(
    'x86_64'
)
url="https://github.com/ArtsyMacaw/wlogout"
source=("$pkgname::git+$url.git")
sha512sums=('SKIP')
provides=('wlogout')
conflicts=('wlogout')

pkgver() {
    cd "$pkgname"
    git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}


build() {
    cd "$pkgname"
    meson setup \
        -Dwerror=false \
        --prefix /usr \
        "$srcdir/build"
    ninja -C "$srcdir/build"
}

package() {
    cd "$pkgname"
    DESTDIR="$pkgdir" ninja -C "$srcdir/build" install
    install -Dm644 -t "$pkgdir/usr/share/doc/${pkgname%-git}" ./*.md
    install -Dm644 -t "$pkgdir/usr/share/licenses/${pkgname%-git}" ./LICENSE

}

# vim: set ft=sh ts=4 sw=4 et: