# Maintainer: Christian Schendel <doppelhelix@gmail.com>

pkgname=wlogout
pkgver=1.2.2
pkgrel=2
license=(MIT)
pkgdesc="Logout menu for wayland"
makedepends=(
    meson
    git
    scdoc
    ninja
)
depends=(
    glib2
    glibc
    gtk3
    gobject-introspection
    gtk-layer-shell
)
optdepends=(
    'swaylock: default buttons'
    'systemd: default buttons'
)
arch=(
    'x86_64'
)
url="https://github.com/ArtsyMacaw/wlogout"
source=(
    "$pkgname-$pkgver.tar.gz::https://github.com/ArtsyMacaw/$pkgname/releases/download/$pkgver/$pkgname.tar.gz"
    "$pkgname-$pkgver.tar.gz.sig::https://github.com/ArtsyMacaw/$pkgname/releases/download/$pkgver/$pkgname.tar.gz.sig"
)
validpgpkeys=("F4FDB18A9937358364B276E9E25D679AF73C6D2F")

b2sums=('b07fc9374b48207c8b7f6570566e2840c5cad4bf6009911936ad632408721c3c371af0a5f8bcaef68e2c7c4090c9343c7d1e43f67de78dd18f704cb0138f0e9b'
        'SKIP')
build() {
    cd "$srcdir"
    meson setup build --prefix /usr
    ninja -C build
}

package() {
    DESTDIR="$pkgdir" ninja -C build install
    install -Dm644 -t "$pkgdir/usr/share/doc/$pkgname" ./*.md
    install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" ./LICENSE

}

# vim: set ft=sh ts=4 sw=4 et: