# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: Alex Potapenko <opotapenko@gmail.com>

pkgname=zapzap
_pkgname=com.rtosta.zapzap
pkgver=6.2.5
pkgrel=1
arch=('any')
pkgdesc='WhatsApp desktop application written in Pyqt6 + PyQt6-WebEngine'
url="https://github.com/rafatosta/$pkgname"
license=(
    GPL-3.0-or-later
)
depends=(
    dbus-python
    hicolor-icon-theme
    python
    python-inflect
    python-jaraco.text
    python-pydantic
    python-pyqt6
    python-pyqt6-webengine
    python-typing_extensions
    qt6-wayland
)
makedepends=(
    desktop-file-utils
    git
    python-build
    python-installer
    python-setuptools
    python-wheel
)
optdepends=(
    'hunspell: spell check'
)
source=(
    "$pkgname-$pkgver::git+$url.git#tag=$pkgver"
    "tray-icon.patch"
)
b2sums=('861eb0686ee19d4454697a2003ccce37365752029895d70813356d8e271749dac79a0cb3fe9d31c934613e07fa9d76b18bf0aba3f1d6dc5039cc3264a566aa99'
        'e8254f81a87a08609096e76156dd8ec37f87ac7c4323d62aaac83f7378fe9273c6fd40d3f214bf6f36346123d628fa587c4b4c7057f4291b66a0c0f8d95c635c')

prepare() {
    cd "${pkgname}-${pkgver}"
    patch -Np1 -i ../tray-icon.patch
}

build() {
    cd "$pkgname-$pkgver"
    python -m build --wheel --no-isolation
}

package() {
    cd "$pkgname-$pkgver"
    python -m installer --destdir="$pkgdir" dist/*.whl
    install -Dm644 share/icons/$_pkgname.svg \
        "$pkgdir"/usr/share/icons/hicolor/scalable/apps/$_pkgname.svg
    install -Dm664 share/applications/$_pkgname.desktop \
        "$pkgdir"/usr/share/applications/$_pkgname.desktop
    install -Dm664 share/metainfo/$_pkgname.appdata.xml \
        "$pkgdir"/usr/share/metainfo/$_pkgname.appdata.xml
}