# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: Alex Potapenko <opotapenko@gmail.com>

pkgname=zapzap
_pkgname=com.rtosta.zapzap
_pkgver=6.2.1.1
pkgver=6.2.1.1
pkgrel=1
arch=('any')
pkgdesc='WhatsApp desktop application written in Pyqt6 + PyQt6-WebEngine'
url="https://github.com/rafatosta/$pkgname"
license=(
    GPL-3.0-or-later
)
depends=(
    dbus-python
    hicolor-icon-theme
    python
    python-inflect
    python-jaraco.text
    python-pydantic
    python-pyqt6
    python-pyqt6-webengine
    python-typing_extensions
    qt6-wayland
)
makedepends=(
    desktop-file-utils
    git
    python-build
    python-installer
    python-setuptools
    python-wheel
)
optdepends=(
    'hunspell: spell check'
)
source=(
    "$pkgname-$_pkgver::git+$url.git#tag=$_pkgver"
)
b2sums=('febf0a16660d27ffbfd29a8cd5ff4c89125c5c861f005bcc1fdb760eee8597e8994221965670a0dcecf81d2016e66f4899e92ad79b025181eb3d8065193216e7')

build() {
    cd "$pkgname-$_pkgver"
    python -m build --wheel --no-isolation
}

package() {
  cd "$pkgname-$_pkgver"
  python -m installer --destdir="$pkgdir" dist/*.whl
  install -Dm644 share/icons/$_pkgname.svg "$pkgdir"/usr/share/icons/hicolor/scalable/apps/$_pkgname.svg
  install -Dm664 share/applications/$_pkgname.desktop "$pkgdir"/usr/share/applications/$_pkgname.desktop
  install -Dm664 share/metainfo/$_pkgname.appdata.xml "$pkgdir"/usr/share/metainfo/$_pkgname.appdata.xml
}