# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: Luis Vervaet <luisvervaet@gmail.com>
# Contributor: Peter Jung <admin@ptr1337.dev>
# Contributor: NextWorks <nextworks@protonmail.com>
# Contributor: Alad Wenter <alad@archlinux.org>
# Contributor: Luna Jernberg <droidbittin@gmail.com>
# Contributor: Hilton Medeiros <medeiros.hilton@gmail.com>
# Contributor: Simon Brulhart <simon@brulhart.me>
# Contributor: Det <nimetonmaili g-mail>, Achilleas Pipinellis, speed145a, Schnouki, aus

pkgname=zen-browser-bin
_pkgname=zen-browser
_desktopname=zen
pkgver=1.17.6b
pkgrel=1
pkgdesc="Performance oriented Firefox-based web browser"
arch=('x86_64' 'aarch64')
url="https://github.com/zen-browser/desktop"
license=(MPL-2.0)
optdepends=(
    'ffmpeg: H264/AAC/MP3 decoding'
    'networkmanager: Location detection via available WiFi networks'
    'libnotify: Notification integration'
    'pulse-native-provider: Audio support'
    'speech-dispatcher: Text-to-Speech'
    'hunspell-en_US: Spell checking, American English'
)
backup=(
    "opt/$pkgname/distribution/policies.json"
)
options=(!strip)
provides=("zen-browser=$pkgver")
conflicts=('zen-browser')
source_x86_64=(
    "zen-browser-$pkgver-$pkgrel-x86_64.tar.xz::https://github.com/zen-browser/desktop/releases/download/$pkgver/zen.linux-x86_64.tar.xz"
)
source_aarch64=(
    "zen-browser-$pkgver-$pkgrel-aarch64.tar.xz::https://github.com/zen-browser/desktop/releases/download/$pkgver/zen.linux-aarch64.tar.xz"
)
source=(
    "$_pkgname.sh"
    "$_desktopname.desktop"
    "policies.json"
    "https://raw.githubusercontent.com/zen-browser/flatpak/refs/heads/main/app.zen_browser.zen.metainfo.xml"
)
b2sums=('710370ba1559605ecf93c5a0a6bbe981628ad8ad49e00770cbc4318d9452cde570f9e5116a692327c55a562ee097c04996ff9a01a61be237c2d83f64eea00e5c'
        'c05f89fa3101dfd1bdb9588867a7531f864ead8ff34c125411a6d528cfc8fc592985bba8f33c921be27ef5138051910d9d030ead202b5f85322c68e167ac0842'
        '328a8ffee9810b03a42fe9b33aa9811e1501b6c4f30db4881355a074615d7146246f94e30210dc1c87a0f6f437dd847164a6dbddf898fad030eb8e9741f3da83'
        'e5d09f55a9e63c1ea5fbab95e40376b959161f853859e27fb365d4a899d36ff01b69ca4191f659d4522cf60351b9127ce18d95ff8cd91418de15217d117f7ca0')
b2sums_x86_64=('f5802a0108cb94f6af6588f17ac17ffabad3c1eb5b2cdbda54b86b181727eb450aaf504459c1f38a86b6c1d5aee92775aff93c3642fa7269b5007ba20f6832ad')
b2sums_aarch64=('6668d1119544820ccef3531e45ab8717378504f6d349f76255e14d21328a60d69c3d27e281620371d1aa1d70d068ad2b3c98dec833b1dcc1cbb7c6066e26d9e2')

package() {
    depends+=(
        alsa-lib
        at-spi2-core
        bash
        cairo
        dbus
        dbus-glib
        gcc-libs
        gdk-pixbuf2
        glib2
        glibc
        gtk3
        fontconfig
        freetype2
        hicolor-icon-theme
        libxcomposite
        libx11
        libxcb
        libxcursor
        libxdamage
        libxext
        libxfixes
        libxi
        libxrandr
        libxrender
        libxt
        mime-types
        nspr
        nss
        pango
        ttf-font
        systemd
    )

    # Create directories
    mkdir -p "$pkgdir"/usr/bin
    mkdir -p "$pkgdir"/usr/share/applications
    mkdir -p "$pkgdir"/usr/share/metainfo
    mkdir -p "$pkgdir"/opt

    # Install
    cp -r zen/ "$pkgdir"/opt/$pkgname

    # Launchers
    install -m755 $_pkgname.sh "$pkgdir"/usr/bin/$_pkgname

    # Desktops
    install -m644 ./*.desktop "$pkgdir"/usr/share/applications/

    # Icons
    for i in 16x16 32x32 48x48 64x64 128x128; do
        install -d "$pkgdir"/usr/share/icons/hicolor/$i/apps/
        ln -s /opt/$pkgname/browser/chrome/icons/default/default${i/x*}.png \
          "$pkgdir"/usr/share/icons/hicolor/$i/apps/$_pkgname.png
    done

    # metainfo
    sed -i 's/app.zen_browser.zen.desktop/zen.desktop/' \
        "${srcdir}/app.zen_browser.zen.metainfo.xml"
    install -Dvm644 "${srcdir}/app.zen_browser.zen.metainfo.xml" \
        "$pkgdir/usr/share/metainfo/app.zen_browser.zen.metainfo.xml"

    # Use system-provided dictionaries
    ln -Ts /usr/share/hunspell "$pkgdir"/opt/$pkgname/dictionaries
    ln -Ts /usr/share/hyphen "$pkgdir"/opt/$pkgname/hyphenation

    # Use system certificates
    ln -sf /usr/lib/libnssckbi.so "$pkgdir"/opt/$pkgname/libnssckbi.so

    # Disable update checks (managed by pacman)
    mkdir "$pkgdir"/opt/$pkgname/distribution
    install -m644 "$srcdir"/policies.json "$pkgdir"/opt/$pkgname/distribution/
}

# vim: set ft=sh ts=4 sw=4 et: