# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: Luis Vervaet <luisvervaet@gmail.com>
# Contributor: Peter Jung <admin@ptr1337.dev>
# Contributor: NextWorks <nextworks@protonmail.com>
# Contributor: Alad Wenter <alad@archlinux.org>
# Contributor: Luna Jernberg <droidbittin@gmail.com>
# Contributor: Hilton Medeiros <medeiros.hilton@gmail.com>
# Contributor: Simon Brulhart <simon@brulhart.me>
# Contributor: Det <nimetonmaili g-mail>, Achilleas Pipinellis, speed145a, Schnouki, aus

pkgname=zen-browser-bin
_pkgname=zen-browser
_desktopname=zen
pkgver=1.16.2b
pkgrel=1
pkgdesc="Performance oriented Firefox-based web browser"
arch=('x86_64' 'aarch64')
url="https://github.com/zen-browser/desktop"
license=(MPL-2.0)
optdepends=(
    'ffmpeg: H264/AAC/MP3 decoding'
    'networkmanager: Location detection via available WiFi networks'
    'libnotify: Notification integration'
    'pulse-native-provider: Audio support'
    'speech-dispatcher: Text-to-Speech'
    'hunspell-en_US: Spell checking, American English'
)
backup=(
    "opt/$pkgname/distribution/policies.json"
)
options=(!strip)
provides=("zen-browser=$pkgver")
conflicts=('zen-browser')
source_x86_64=(
    "zen-browser-$pkgver-$pkgrel-x86_64.tar.xz::https://github.com/zen-browser/desktop/releases/download/$pkgver/zen.linux-x86_64.tar.xz"
)
source_aarch64=(
    "zen-browser-$pkgver-$pkgrel-aarch64.tar.xz::https://github.com/zen-browser/desktop/releases/download/$pkgver/zen.linux-aarch64.tar.xz"
)
source=(
    "$_pkgname.sh"
    "$_desktopname.desktop"
    "policies.json"
)
b2sums=('710370ba1559605ecf93c5a0a6bbe981628ad8ad49e00770cbc4318d9452cde570f9e5116a692327c55a562ee097c04996ff9a01a61be237c2d83f64eea00e5c'
        '807cda3666f71ce4da67cbfe8270b4e8594a74af136ab526973524c8cd856e53283a4b6330154bf3802cc90cc42f49c090091237210615df844da3312c64a377'
        '328a8ffee9810b03a42fe9b33aa9811e1501b6c4f30db4881355a074615d7146246f94e30210dc1c87a0f6f437dd847164a6dbddf898fad030eb8e9741f3da83')
b2sums_x86_64=('2ec38f1df7364699ba218510e9d59620e8731b79c8e124f9db5752a73598c733ee0483c70de17b5c8f62b3f838fc113247d43648750d5866e4231bf287d4ecf9')
b2sums_aarch64=('89910b5621d2fd8ad6aba623570ac9c4b75c792edb2d7061a598b19c104cfd4439dbaaad946a2b59ed4210e9329551666ed35a9ad99620d5e1100acb6f797f74')

package() {
    depends+=(
        alsa-lib
        at-spi2-core
        bash
        cairo
        dbus
        dbus-glib
        gcc-libs
        gdk-pixbuf2
        glib2
        glibc
        gtk3
        fontconfig
        freetype2
        hicolor-icon-theme
        libxcomposite
        libx11
        libxcb
        libxcursor
        libxdamage
        libxext
        libxfixes
        libxi
        libxrandr
        libxrender
        libxt
        mime-types
        nspr
        nss
        pango
        ttf-font
        systemd
    )

    # Create directories
    mkdir -p "$pkgdir"/usr/bin
    mkdir -p "$pkgdir"/usr/share/applications
    mkdir -p "$pkgdir"/opt

    # Install
    cp -r zen/ "$pkgdir"/opt/$pkgname

    # Launchers
    install -m755 $_pkgname.sh "$pkgdir"/usr/bin/$_pkgname

    # Desktops
    install -m644 ./*.desktop "$pkgdir"/usr/share/applications/

    # Icons
    for i in 16x16 32x32 48x48 64x64 128x128; do
        install -d "$pkgdir"/usr/share/icons/hicolor/$i/apps/
        ln -s /opt/$pkgname/browser/chrome/icons/default/default${i/x*}.png \
          "$pkgdir"/usr/share/icons/hicolor/$i/apps/$_pkgname.png
    done

    # Use system-provided dictionaries
    ln -Ts /usr/share/hunspell "$pkgdir"/opt/$pkgname/dictionaries
    ln -Ts /usr/share/hyphen "$pkgdir"/opt/$pkgname/hyphenation

    # Use system certificates
    ln -sf /usr/lib/libnssckbi.so "$pkgdir"/opt/$pkgname/libnssckbi.so

    # Disable update checks (managed by pacman)
    mkdir "$pkgdir"/opt/$pkgname/distribution
    install -m644 "$srcdir"/policies.json "$pkgdir"/opt/$pkgname/distribution/
}

# vim: set ft=sh ts=4 sw=4 et: