# Maintainer: Christian Schendel <doppelhelix@gmail.com>
# Contributor: Luis Vervaet <luisvervaet@gmail.com>
# Contributor: Peter Jung <admin@ptr1337.dev>
# Contributor: NextWorks <nextworks@protonmail.com>
# Contributor: Alad Wenter <alad@archlinux.org>
# Contributor: Luna Jernberg <droidbittin@gmail.com>
# Contributor: Hilton Medeiros <medeiros.hilton@gmail.com>
# Contributor: Simon Brulhart <simon@brulhart.me>
# Contributor: Det <nimetonmaili g-mail>, Achilleas Pipinellis, speed145a, Schnouki, aus

pkgname=zen-browser-bin
_pkgname=zen-browser
_desktopname=app.zen_browser.zen
pkgver=1.17.3b
pkgrel=1
pkgdesc="Performance oriented Firefox-based web browser"
arch=('x86_64' 'aarch64')
url="https://github.com/zen-browser/desktop"
license=(MPL-2.0)
optdepends=(
    'ffmpeg: H264/AAC/MP3 decoding'
    'networkmanager: Location detection via available WiFi networks'
    'libnotify: Notification integration'
    'pulse-native-provider: Audio support'
    'speech-dispatcher: Text-to-Speech'
    'hunspell-en_US: Spell checking, American English'
)
backup=(
    "opt/$pkgname/distribution/policies.json"
)
options=(!strip)
provides=("zen-browser=$pkgver")
conflicts=('zen-browser')
source_x86_64=(
    "zen-browser-$pkgver-$pkgrel-x86_64.tar.xz::https://github.com/zen-browser/desktop/releases/download/$pkgver/zen.linux-x86_64.tar.xz"
)
source_aarch64=(
    "zen-browser-$pkgver-$pkgrel-aarch64.tar.xz::https://github.com/zen-browser/desktop/releases/download/$pkgver/zen.linux-aarch64.tar.xz"
)
source=(
    "$_pkgname.sh"
    "$_desktopname.desktop"
    "policies.json"
    "https://raw.githubusercontent.com/zen-browser/flatpak/refs/heads/main/app.zen_browser.zen.metainfo.xml"
)
b2sums=('710370ba1559605ecf93c5a0a6bbe981628ad8ad49e00770cbc4318d9452cde570f9e5116a692327c55a562ee097c04996ff9a01a61be237c2d83f64eea00e5c'
        '807cda3666f71ce4da67cbfe8270b4e8594a74af136ab526973524c8cd856e53283a4b6330154bf3802cc90cc42f49c090091237210615df844da3312c64a377'
        '328a8ffee9810b03a42fe9b33aa9811e1501b6c4f30db4881355a074615d7146246f94e30210dc1c87a0f6f437dd847164a6dbddf898fad030eb8e9741f3da83'
        '380f7ff533d95f654b0af0ed442b3318fa2392cb1037bb356ade4618c964939f9981e102ff3525a4b57380a97f59d9093af97d7c9fc5915168ba0b147ae41fd1')
b2sums_x86_64=('0cf19c62a890c766415bc5930a0c74d9470fdda54d687ea7f467c86e5a4f95bfe9b1181dedbfe285cb5ed04658f7ab65103883d7d2a2744d1458bede46d8e498')
b2sums_aarch64=('0a50dff785aecc8373dd2512a460dd9c6efdb3bd1ae12959995baba1b915bb2439fc5b3cd0e26d9384f6d1da4974159a589add0fe907f2194fa45cdc88da7d9a')

package() {
    depends+=(
        alsa-lib
        at-spi2-core
        bash
        cairo
        dbus
        dbus-glib
        gcc-libs
        gdk-pixbuf2
        glib2
        glibc
        gtk3
        fontconfig
        freetype2
        hicolor-icon-theme
        libxcomposite
        libx11
        libxcb
        libxcursor
        libxdamage
        libxext
        libxfixes
        libxi
        libxrandr
        libxrender
        libxt
        mime-types
        nspr
        nss
        pango
        ttf-font
        systemd
    )

    # Create directories
    mkdir -p "$pkgdir"/usr/bin
    mkdir -p "$pkgdir"/usr/share/applications
    mkdir -p "$pkgdir"/usr/share/metainfo
    mkdir -p "$pkgdir"/opt

    # Install
    cp -r zen/ "$pkgdir"/opt/$pkgname

    # Launchers
    install -m755 $_pkgname.sh "$pkgdir"/usr/bin/$_pkgname

    # Desktops
    install -m644 ./*.desktop "$pkgdir"/usr/share/applications/

    # Icons
    for i in 16x16 32x32 48x48 64x64 128x128; do
        install -d "$pkgdir"/usr/share/icons/hicolor/$i/apps/
        ln -s /opt/$pkgname/browser/chrome/icons/default/default${i/x*}.png \
          "$pkgdir"/usr/share/icons/hicolor/$i/apps/$_pkgname.png
    done

    # metainfo
    install -m644 ./*.metainfo.xml "$pkgdir"/usr/share/metainfo/

    # Use system-provided dictionaries
    ln -Ts /usr/share/hunspell "$pkgdir"/opt/$pkgname/dictionaries
    ln -Ts /usr/share/hyphen "$pkgdir"/opt/$pkgname/hyphenation

    # Use system certificates
    ln -sf /usr/lib/libnssckbi.so "$pkgdir"/opt/$pkgname/libnssckbi.so

    # Disable update checks (managed by pacman)
    mkdir "$pkgdir"/opt/$pkgname/distribution
    install -m644 "$srcdir"/policies.json "$pkgdir"/opt/$pkgname/distribution/
}

# vim: set ft=sh ts=4 sw=4 et: